home *** CD-ROM | disk | FTP | other *** search
/ SGI Hot Mix 17 / Hot Mix 17.iso / HM17_SGI / research / lib / read_srf.pro < prev    next >
Text File  |  1997-07-08  |  5KB  |  169 lines
  1. ; $Id: read_srf.pro,v 1.5 1997/01/15 03:11:50 ali Exp $
  2. ;
  3. ; Copyright (c) 1987-1997, Research Systems, Inc.  All rights reserved.
  4. ;       Unauthorized reproduction prohibited.
  5.  
  6. PRO READ_SRF, FILE, IMAGE, R, G, B
  7. ;
  8. ;+
  9. ; NAME:
  10. ;    READ_SRF
  11. ;
  12. ; PURPOSE:
  13. ;    Read the contents of a Sun rasterfile and return the image and
  14. ;    color table vectors (if present) in the form of IDL variables.
  15. ;
  16. ; CATEGORY:
  17. ;    Input/Output.
  18. ;
  19. ; CALLING SEQUENCE:
  20. ;    READ_SRF, File, Image [, R, G, B]
  21. ;
  22. ; INPUTS:
  23. ;    File:    Scalar string giving the name of the rasterfile to read
  24. ;
  25. ; OUTPUTS:
  26. ;    Image:    The 2D byte array to contain the image.
  27. ;
  28. ;
  29. ; OPTIONAL OUTPUT PARAMETERS:
  30. ;     R, G, B:    The variables to contain the Red, Green, and Blue color vectors
  31. ;        if the rasterfile containes colormaps.
  32. ;
  33. ; COMMON BLOCKS:
  34. ;    None.
  35. ;
  36. ; SIDE EFFECTS:
  37. ;    None.
  38. ;
  39. ; RESTRICTIONS:
  40. ;    This routine only handles 1, 8, 24, and 32-bit rasterfiles of type
  41. ;    RT_OLD and RT_STANDARD.  See the file /usr/include/rasterfile.h
  42. ;    for the structure of Sun rasterfiles.
  43. ;
  44. ; EXAMPLE:
  45. ;    To open and read the Sun rasterfile named "sun.srf" in the current
  46. ;    directory, store the image in the variable IMAGE1, and store the color
  47. ;    vectors in the variables R, G, and B, enter:
  48. ;
  49. ;        READ_SRF, "sun.srf", IMAGE1, R, G, B
  50. ;
  51. ;    To load the new color table and display the image, enter:
  52. ;
  53. ;        TVLCT, R, G, B
  54. ;        TV, IMAGE1
  55. ; 
  56. ; MODIFICATION HISTORY:
  57. ;    Written fall 1987, AB
  58. ;    3/1/90, Added 24 bit images, DMS.
  59. ;    7/8/90, Added 32 bit images, DMS.
  60. ;    1/22/92, the colors within 24 bit images were not ordered
  61. ;        correctly, DMS.
  62. ;    5/7/96, Corrected bug in the color vector order for 24 bit
  63. ;        images. As per the "Encyclopedia of Graphics File
  64. ;        formats", O'Rielly & Ass., 24 bit pixel data is in
  65. ;        BGR format rather that RGB. This was verified thru
  66. ;        the use of XV. Also the 32 big reading section did
  67. ;        perform the color correction correctly. kdb.
  68. ;-
  69. ; Copyright (c) 1990, Research Systems, Inc.  All rights reserved.
  70. ;    Unauthorized reproduction prohibited.
  71. ;
  72.  
  73. ; Define the Sun Raster File structure
  74. a = {rasterfile, magic:0L, width:0L, height:0L, depth: 0L, $
  75.     length:0L, type:0L, maptype:0L, maplength:0L}
  76.  
  77. OPENR, unit, file, /GET_LUN, /BLOCK
  78.  
  79. READU, unit, a
  80. ; Check the magic number
  81. if (a.magic EQ '956aa659'XL) then begin
  82.     byteorder, a, /ntohl        ;Back to our order
  83.     endif
  84.     
  85. IF (a.magic NE '59a66a95'X) THEN begin
  86.     message, /CONTINUE, 'File ' + file + $
  87.         ' does not have a SUN rasterfile magic number.'
  88.     GOTO, done
  89.     ENDIF
  90.  
  91. ; Only know how to do RT_OLD and RT_STANDARD style rasterfiles.
  92. IF ((a.type NE 0) AND (a.type NE 1)) THEN BEGIN
  93.     message, /CONTINUE, $
  94.         'Don''t know how to handle this style of rasterfile, sorry...'
  95.     GOTO, done
  96.     ENDIF
  97.  
  98. ; Only know how to handle 1 bit and 8 bit images
  99. IF (a.depth NE 1) AND (a.depth NE 8) AND (a.depth ne 24) AND $
  100.    (a.depth ne 32) then begin
  101.     message, /CONTINUE, 'Can''t handle ' + string(a.depth) + ' bit images.'
  102.     GOTO, done
  103.     ENDIF
  104.  
  105. ; Recompute length, since rasterfile.h says you have to for old files...
  106. a.length = (a.width * a.height * a.depth) / 8
  107. image = 0        ;Delete original value of image var
  108.  
  109. ; If image has color tables, read them
  110. IF ( (a.maptype EQ 1) AND (a.maplength NE 0) ) THEN BEGIN
  111.     maplen = a.maplength / 3
  112.     r = BYTARR(maplen)
  113.     g = BYTARR(maplen)
  114.     b = BYTARR(maplen)
  115.     READU, unit, r, g, b
  116.     ENDIF
  117.  
  118. ; Get a byte array for the image
  119.  
  120. ; If the image is 1 bit, read it and decode into bytes
  121. case a.depth of
  122. 1: begin
  123.     ncols = ((a.width + 15)/16)*16  ;# of columns padded to short
  124.     image = BYTARR(ncols, a.height) ;make the array
  125.     temp = intarr(a.length/2)    ; Get the packed shorts
  126.     READU, unit, temp
  127.         mask = ROTATE((2 ^ indgen(16)),2) ;Array of 16 bits
  128.     FOR i = 0,15 DO BEGIN        ;Unpack each bit
  129.         ind = WHERE(temp AND mask[i])
  130.         s = size(ind)
  131.         if (s[0] ne 0) THEN image[ind * 16 + i] = 255
  132.         ENDFOR
  133. ENDCASE
  134.  
  135. 8: BEGIN    ; If the image is eight bit, read it
  136.     ncols = ((a.width + 1)/2)*2  ;Pad to even number
  137.     image = BYTARR(ncols, a.height)
  138.     READU, unit, image
  139. ENDCASE
  140.  
  141. 24: BEGIN        ;24 bit
  142.     ncols = ((3*a.width + 1)/2)*2  ;Pad to even number of bytes
  143.     image = BYTARR(3, a.width, a.height)
  144.     ; Bug fix. RGB vectors are store BGR in standard SRF!
  145.  
  146.     row = bytarr(ncols); read a row at a time.
  147.     indices = [2,1,0] # replicate(1,a.width*3) + $
  148.         (3 * (indgen(a.width*3)/3))
  149.     for i=0, a.height-1 do begin
  150.         readu, unit, row    
  151.         image[0,0,i] = reform(row[indices], 3, a.width, /over)
  152.     endfor
  153. ENDCASE
  154.  
  155. 32:    BEGIN        ;Read 32 bit into a (3,n,m) image
  156.     image = BYTARR(3,a.width, a.height)
  157.     row = bytarr(4,a.width)    ;Read a row at a time
  158.     indices = [3,2,1] # replicate(1,a.width*3) + $
  159.         (4 * (indgen(a.width*3)/3))
  160.     for i=0,a.height-1 do begin
  161.         readu, unit, row
  162.         image[0,0,i] = reform(row[indices],3,a.width,/over)
  163.         endfor
  164. ENDCASE
  165. ENDCASE
  166. done:
  167.     FREE_LUN, unit
  168.     END
  169.